David Ritter responded to our report Novell AFP Server incompatible with Snow Leopard by sharing an Applescript to fix the problem:
I am a tech support person for a chain of weekly newspapers. We use Novell servers at many of our locations. When installing new Macs running Leopard or Snow Leopard we have found that the only way we are able to connect to the Novell servers is to enable "clear text" logins on OS X.
I found a short AppleScript to help with this. I compiled this to a small script app that we use when setting up new OS X installations:
try
set clearStatus to (do shell script "defaults read com.Apple.AppleShareClient afp_cleartext_allow") as number
on error
--the first command will throw an error if the afp_cleartext_allow setting does not exist
--if there is an error we'll assume that the setting isn't there and set our variable to the disabled setting
set clearStatus to 0
end try
--a status of "1" means it's enabled. So ask if they want to disable it
if clearStatus is 1 then
display dialog "Do you want to disable clear text passwords?" buttons {"Cancel", "Disable"} default button 2
if the button returned of the result is "Disable" then
do shell script "defaults write com.Apple.AppleShareClient afp_cleartext_allow -bool NO"
set clearStatus to (do shell script "defaults read com.Apple.AppleShareClient afp_cleartext_allow") as number
--check to make sure the change really took effect
if clearStatus is 0 then
display dialog "Clear text passwords have been disabled" buttons {"OK"}
else
display dialog "There was an error disabling clear text passwords!" buttons {"OK"}
end if
end if
else
display dialog "Do you want to enable clear text passwords?" buttons {"Cancel", "Enable"} default button 2
if the button returned of the result is "Enable" then
do shell script "defaults write com.Apple.AppleShareClient afp_cleartext_allow -bool YES"
set clearStatus to (do shell script "defaults read com.Apple.AppleShareClient afp_cleartext_allow") as number
--check to make sure the change really took effect
if clearStatus is 1 then
display dialog "Clear text passwords have been enabled" buttons {"OK"}
else
display dialog "There was an error enabling clear text passwords!" buttons {"OK"}
end if
end if
end if
If you've tried this suggestion
